pxInitTriMesh%(vbank*,fbank*, MESH_NBVERTICES%, MESH_NBFACES%, file_name$, pMap%)

Параметры

Vbank – банк вершин
Fbank – банк треугольников
MESH_NBVERTICES% – количество вершин
MESH_NBFACES% – количество треугольников
file_name$ – имя файла в котором будет хранится пмап тримеша.
pMap% - качество колизии

Описание

Инициализирует Тримеш, но не создаёт его. Возвращает геометрию будующего Тримеша и создаёт файл с пмапом.. Эта функция вызывается только один раз, перед циклом, для определения одного типа геометрии.
Пмам создаётся только один раз. Его создание занимает продолжительное время и может достигать 1-2 минут. Имя файла должно выглядеть как “newmap.pmap”. Хотя расширения файла может быть любым.
Предупреждение: если пмап уже был создан, а позже вы изменили форму меша, то нужно удалить старый пмап и сгенерировать заново.
pMap - параметр отвечает за качество пМап, который в сою очередь отвечает за качество колизии. Ставятся значения 8, 16, 32, 64, 128, ... Чем больше значение тем лучше Пмап и тем дольше он строится. При значении 128 это можетзаняит несколько минут. По умолчанию ставится 64.

Смотрите так же

Пример

;Пример применения функции
;pxInitTriMesh

;В данном примере нам понадобятся несколько однотипных тел
Type Px_Cube
    Field body%
    Field mesh%
End Type

Graphics3D 800, 600, 32, 2
SetBuffer BackBuffer()

;Создаем физический мир, устанавливаем гравитацию.
pxCreateWorld(1) ;У нас будет поверхность
pxSetGravity(0, -10, 0)

camera=CreateCamera()
light=CreateLight()

PositionEntity camera,0,50,-40
RotateEntity camera,30,0,0

plane=CreatePlane() ;Визуализируем поверхность
EntityColor plane,0,100,200
EntityAlpha plane,0.5
mir = CreateMirror () ;Чуть украсим зеркалом

mesh = LoadMesh("media\Tarelka.3ds")
ScaleMesh mesh,0.2,0.2,0.2
PositionEntity mesh,0,30,0

;создаем банк для тримеша
nsurf = CountSurfaces(mesh)
nvert = 0
nface = 0
For ns = 1 To nsurf
    Local surf = GetSurface(mesh,ns)
    nface = nface+CountTriangles(surf)
    nvert = nvert +CountVertices(surf)
Next

fbank = CreateBank(nface*4*3)
nf = 0
vbank = CreateBank(nvert*4*3)
nv = 0
For ns = 1 To nsurf
    surf = GetSurface(mesh,ns)
    nfv = CountTriangles(surf)
    For nfc = 0 To nfv -1
        PokeInt fbank,nf*12+0,TriangleVertex(surf,nfc,0)
        PokeInt fbank,nf*12+4,TriangleVertex(surf,nfc,1)
        PokeInt fbank,nf*12+8,TriangleVertex(surf,nfc,2)
        nf=nf+1
    Next

    nvv = CountVertices(surf)
    For nvc = 0 To nvv - 1
        PokeFloat vbank,nv*12+0,VertexX(surf,nvc)
        PokeFloat vbank,nv*12+4,VertexY(surf,nvc)
        PokeFloat vbank,nv*12+8,VertexZ(surf,nvc)
        nv = nv+1
    Next
Next
;Инициализируем Тримеш
; ------------ Применяем pxInitTriMesh:
initial_mesh = pxInitTriMesh(vbank, fbank, nvert, nface, "media\tarelka.pm")
FreeBank vbank
FreeBank fbank
HideEntity mesh

ocu.Px_Cube = New Px_Cube
ocu\mesh=CopyMesh(mesh)
ocu\body=pxCreateTriMesh(initial_mesh,10)
pxSetPosition(ocu\body,0,40,0)

;Основной цикл программы
While Not KeyDown(1) ;Пока не нажат ESC

    If KeyHit(57) ;Добавим тельце
        ocu.Px_Cube = New Px_Cube
        ocu\mesh=CopyMesh(mesh)
        ocu\body=pxCreateTriMesh(initial_mesh,10)
        pxSetPosition(ocu\body,Rand(-20,20),50,Rand(-10,20))
    EndIf

;обсчитываем физический мир
    RenderPhysic(60,0)

;Обновим положения всех объектов
    For ocu.Px_Cube = Each Px_Cube
     pxSetEntity(ocu\mesh, ocu\body)
    Next

    RenderWorld
    Text 10,10, "Пробел - Добавить тело"
    Flip
Wend
End

К содержанию

Нажмите здесь чтобы увидеть последнюю версию этой странички в режиме online.